elvish_config/lib/moi/util/map.elv

fn empty [container]{ == (count $container) 0 }

fn values [container]{ keys $container | each [v]{ put $container[$v] } }
fn pvalues [container]{ keys $container | peach [v]{ put $container[$v] } }

fn value-of [container k &default=$nil]{
  if (has-key $container $k) {
    put $container[$k]
  } else {
    put $default
  }
}

fn unzip [container]{
  local:lkeys local:lvalues = [] []
  keys $container | each [k]{
    lkeys = [(all $lkeys) $k]
    lvalues = [(all $lvalues) $container[$k]]
  }
  put $lkeys $lvalues
}

fn zip [lkeys lvalues]{
  use ./condition
  local:ck local:cv = (count $lkeys) (count $lvalues)
  local:c = (condition:set (> $ck $cv) $cv $ck)
  local:result = [&]
  range $c | peach [i]{
    put [&k=$lkeys[$i] &i=$i]
  } | peach [e]{
    assoc $e v $lvalues[$e[i]]
  } | each [e]{
    result[$e[k]] = $e[v]
  }
  put $result
}

fn to-map [@argv]{
  use ./list
  local:container = (list:to-list $@argv)
  zip [(range (count $container))] $container
}

fn to-set [@argv]{
  use ./list
  local:m = [&]
  each [k]{ m[$k] = $nil } (list:to-list $@argv)
  put $m
}

fn mdissoc [container @argv]{
  each [k]{
    container = (dissoc $container $k)
  } $argv
  put $container
}

fn massoc [&replace=$true container @argv]{
  each [e]{
    local:k local:v = $@e
    if (or $replace (not (has-key $container $k))) {
      container[$k] = $v
    }
  } $argv
  put $container
}

fn add [container key @values]{
  use ./list
  local:values = (list:to-list $values)
  if (has-key $container $key) {
    container[$key] = [(all $container[$key]) $@values]
  } else {
    container[$key] = $values
  }
  put $container
}

fn join [container container2]{
  keys $container2 | each [k]{
    container[$k] = $container2[$k]
  }
  put $container
}

fn sorted-keys [&reverse=$false &less-than=$nil container]{
  keys $container | order &reverse=$reverse &less-than=$less-than
}

fn sorted-values [&reverse=$false &less-than=$nil container]{
  values $container | order &reverse=$reverse &less-than=$less-than
}