edit:add-var ipof~ [@argv]{
  use str
  use moi/util/condition
  use moi/util/ip

  fn less [cmp e1 e2]{ < ($cmp $e1 $e2) 0 }

  fn sort-ip [e1 e2]{
    var i1 = (condition:cset (ip:is-ipv4 $e1) 0 (condition:cset (ip:is-ipv6 $e1) 1 2))
    var i2 = (condition:cset (ip:is-ipv4 $e2) 0 (condition:cset (ip:is-ipv6 $e2) 1 2))
    if (!= $i1 $i2) {
      < $i1 $i2
    } elif (== $i1 2) {
      <s $e1 $e2
    } elif (== $i1 1) {
      less $ip:cmp6~ $e1 $e2
    } else {
      less $ip:cmp4~ $e1 $e2
    }
  }

  fn dnssolve [d]{
    var result = [
      &ips=[&]
      &resolvers=''
      &txt=''
    ]
    e:dnscrypt-proxy -config /etc/dnscrypt-proxy/dnscrypt-proxy.toml -resolve (idn -a $d) | peach [l]{
      var ll    = $l
      var idx   = (+ (str:index $ll :) 1)
      var value = (str:trim-space $ll[$idx".."])
      if (or (str:has-prefix $ll 'IPv4 addresses') (str:has-prefix $ll 'IPv6 addresses')) {
        str:split ', ' $value | peach [e]{
          var ee = $e
          if (ip:is-ip $ee) {
            result[ips][$ee] = $nil
          }
        }
      } elif (str:has-prefix $ll 'TXT records') {
        result[txt] = $value
      } elif (str:has-prefix $ll 'Resolver') {
        result[resolvers] = $value
      } elif (str:has-prefix $ll 'Name servers') {
        result[remote] = (not-eq $value 'name does not exist')
      }
    }
    put $result
  }

  var hosts = [&]
  cat /etc/hosts | peach [l]{
    var ll = (str:trim-space $l)
    if (and (not-eq $ll '') (not-eq $ll[0] '#')) {
      put $ll
    }
  } | eawk [_ ip @domains]{
    peach [d]{
      var dd = $d
      if (has-key $hosts $dd) {
        hosts[$dd][$ip] = $nil
      } else {
        hosts[$dd] = [&$ip=$nil]
      }
    } $domains
  }

  var remote = [&]
  peach [d]{
    var dd    = $d
    var solve = (dnssolve $dd)
    if (> (keys $solve[ips] | count) 0) {
      remote[$dd] = $solve
    }
  } $argv

  each [d]{
    var exists = $false
    echo (styled 'Resolving '$d'…' bright-green)
    echo
    if (has-key $hosts $d) {
      exists = $true
      echo (styled '  local:' bright-yellow)
      keys $hosts[$d] | order &less-than=$sort-ip~ | each [ip]{
        echo '    - '$ip
      }
    }
    if (and (has-key $remote $d) $remote[$d][remote]) {
      exists = $true
      var info = $remote[$d]
      echo (styled '  remote:' bright-yellow)
      echo '    IPs:'
      keys $info[ips] | order &less-than=$sort-ip~ | each [ip]{
        echo '    - '$ip
      }
      echo '    Resolvers:   '$info[resolvers]
      echo '    TXT records: '$info[txt]
    }
    if (not $exists) {
      echo (styled 'No info found' bright-red)
    }
    echo
  } $argv
}